pkgname=libhybris-git
_pkgname=libhybris
pkgver=375.d090299
pkgrel=1
pkgdesc="Libhybris allows to use librarys compiled against bionic (e. g. Android driver) under an glibc based Linux (like Arch Linux ARM)."
arch=('armv7h')
url="https://github.com/libhybris/libhybris"
license=('Apache')
depends=('android-system')
makedepends=('android-headers')
provides=('libhybris')
conflicts=('libhybris')
source=("libhybris::git+https://github.com/libhybris/libhybris" "hybris.conf" "15-hybris.rules")
install=${_pkgname}.install
md5sums=('SKIP'
         '1bfa641d02dedf14e6b84dfdc685d5b3'
         '01e0ba913443fb34dbe56df0dcf58af9')
options=('!strip')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

build() {
  cd "${srcdir}/${_pkgname}/hybris"

  export CFLAGS="${CFLAGS} -g"

  ./autogen.sh \
    --prefix=/opt/hybris \
    --with-android-headers=/opt/android-headers \
    --enable-wayland \
    --enable-mesa \
    --with-default-egl-platform=fbdev


  make
}

package() {
  cd "${srcdir}/${_pkgname}/hybris"

  mkdir -p "${pkgdir}/opt/hybris"
  mkdir -p "${pkgdir}/etc/modules-load.d"
  mkdir -p "${pkgdir}/usr/lib/udev/rules.d"

  make DESTDIR="${pkgdir}" install

  install -Dm644 ../../hybris.conf "${pkgdir}/etc/modules-load.d"
  install -Dm644 ../../15-hybris.rules "${pkgdir}/usr/lib/udev/rules.d"
}
