# ArmSoc (OMAP + Mali)  FrameBuffer driver for Xorg from Linaro.
# Maintainer: Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: Erik Andersson <erik.h.andersson@gmail.com>
# Contributor: Adam Gashlin <agashlin@gmail.com>

buildarch=4

pkgname=xf86-video-armsoc
pkgver=1.0.0
pkgrel=1
arch=('armv7h')
url="http://cgit.freedesktop.org/xorg/driver/xf86-video-armsoc"
license=('GPL2')
makedepends=('git' 'pkgconfig' 'xorg-server-devel' 'resourceproto' 'scrnsaverproto')
options=('!libtool')
source=(
  "$pkgname::git://anongit.freedesktop.org/xorg/driver/xf86-video-armsoc#tag=${pkgver}"
  "0001-no-hwcursor.patch"
  "0002-no-NullEXA.patch"
  "0004-vt-switch.patch"
  "0005-resize-without-dri.patch"
)
md5sums=(
  'SKIP'
  'd975fcff7e8db79427c3850000123166'
  'a4ef21ab53c4ae5522781c06c72c47b9'
  '4d21acedf86adcede86e07d697518474'
  '4b3810f3b31fcd6903bb53af28d1b9aa'
)

prepare() {
  cd $pkgname

  git apply ../0001-no-hwcursor.patch
  git apply ../0002-no-NullEXA.patch
  git apply ../0004-vt-switch.patch
  git apply ../0005-resize-without-dri.patch

  CFLAGS=`echo $CFLAGS | sed -e 's/vfpv3-d16/neon/'` && CXXFLAGS="$CFLAGS"
  ./autogen.sh --prefix=/usr --with-drmmode=exynos
}

build() {
  cd $pkgname

  CFLAGS=`echo $CFLAGS | sed -e 's/vfpv3-d16/neon/'` && CXXFLAGS="$CFLAGS"
  make
}

package() {
  cd $pkgname

  make DESTDIR="${pkgdir}" install
}

